Vim

From Wiki
Jump to navigation Jump to search

https://www.vim.org/

This page is about editing ConTeXt source in Vim, gVim, MacVim, and other Vim clones. The page describes the scripts available in Vim v8.0.0055 or later. If you are using Vim 7, see Using the scripts with an older Vim below.

If you feel that something is missing, please contribute!

Information about providing feedback is in the header of the scripts.

Using ConTeXt in Vim

Nikolai Weibull was the first one who wrote context.vim files and submitted them to the official Vim repository. They are part of the official Vim 7, and were expanded and improved in Vim 8. Starting with Vim 9.0.0218, the scripts supporting ConTeXt in Vim have been rewritten in Vim 9 script (the new Vim's scripting language). For the complete documentation, see :help ft-context.

Asciicast

context-in-vim.png

This asciicast[1] gives you a taste of ConTeXt editing in Vim.

Typesetting

The recommended way to typeset a ConTeXt document is to use the :ConTeXt command. Just type:

:ConTeXt %

to compile the document in the current buffer. Typesetting happens in the background, so you may continue working on your document. If there are errors, the quickfix window will open automatically to show the errors (one per line). The cursor will stay in the main document, so your typing workflow will not be disrupted. You may use standard quickfix commands to jump between errors: :cfirst, :cprev, :cnext, etc… (see :help quickfix). See below for useful mappings for these commands.

If your document is typeset without errors, Success! is printed at the bottom of the screen.

The :ConTeXt command accepts an optional path, in case you want to typeset a document different from the current one (useful for big projects).

You may check the status of your ConTeXt jobs with :ConTeXtJobStatus, and you may stop all running jobs with :ConTeXtStopJobs.

Setting a custom typesetting engine

The :ConTeXt command invokes the mtxrun script that is found in $PATH. For more fine grained control over the command and its environment, you may invoke context.Typeset() directly (or context#Typeset() from legacy Vim script). For instance, if you have installed a version of ConTeXt in $HOME/context (where $HOME is the path to your home directory), you may define a function to use it similar to the following (you may put the following code in ~/.vim/after/ftplugin/context.vim, creating the file and the directories if they do not exist):

import autoload 'context.vim'
def MyConTeXt()
  const env = {'PATH': printf("%s/context/tex/texmf-<os>-<arch>/bin:%s", $HOME, $PATH)}
  context.Typeset("%", env)
enddef

and perhaps use it with a mapping:

nnoremap <silent><buffer><leader>t <scriptcmd>MyConTeXt()<cr>

context.Typeset() accepts a third optional argument to specify a custom typesetting command. That must be a function that takes a path and returns the command as a List. For example:

def ConTeXtCustomCommand(path: string): list<string>
  return ['mtxrun', '--script', 'context', '--nonstopmode', path]
enddef
context.ConTeXtTypeset("%", v:none, ConTeXtCustomCommand)

Working with large projects

Large projects are often organized as a root document and various chapter files. When editing a chapter file, it is convenient to invoke :ConTeXt directly on it, rather than having to switch to the root file. A “magic line” can be added at the beginning of each chapter file, which specifies the relative path to the root file. For instance:

% !TEX root = ../MyRoot.tex

Vim searches for the magic line in the first ten lines of the current buffer: if the magic line is found, the document specified by that line is typeset rather than the one in the current buffer. The root document does not have to be opened in Vim.

Updating the syntax files

Vim includes syntax files generated by mtxrun. If you want to use more up-to-date files, overriding those distributed with Vim, you may proceed as follows. Assuming your Vim configuration lives in ~/.vim, you may type:

mkdir -p ~/.vim/syntax/shared
cd ~/.vim/syntax/shared
mtxrun --script interface --vim

The last command will create the following syntax files:

  • context-data-context.vim;
  • context-data-interfaces.vim;
  • context-data-metafun.vim;
  • context-data-tex.vim.

Editing features

You may use the following commands to quickly jump to different parts of your document:

  • [[: jump to the previous start of subject, section, chapter, part, component, or product;
  • ]]: jump to the next start of subject, section, chapter, part, component, or product;
  • []: jump to the previous end of section, chapter, etc…;
  • ][: jump to the next end of section, chapter, etc…;
  • [{: jump to the previous \start… or \setup… command;
  • ]}: jump to the next \stop… or \setup… command;

Each of the above accepts an optional count. For example, you may type 3[{ to jump three \start… commands before.

You may use the following ConTeXt-specific text objects, to be used in Visual or Operator-pending mode (see :help text-objects):

  • i$: inside $…$ (dollars excluded);
  • a$: around $…$ (dollars included);
  • tp: a ConTeXt paragraph.

So, for example, you may copy (“yank” in Vim's jargon) a paragraph by typing ytp (“yank a TeX paragraph“), delete it with dtp, select it with vtp, reflow it with gqtp, etc… Similarly, you may yank a formula with vi$ (or va$), and delete it, select it, etc…, in a similar fashion.

If you have enabled the matchit plugin included in Vim (see :help matchit), you may also type % to jump between matching \start… and \stop… commands, or between matching parentheses.

You may jump to a different file by positioning the cursor over the file name and typing gf (:help gf). For example, if you have the following in your document:

\component my_component

putting the cursor over my_component and pressing gf will open my_component.tex.

Similarly, you may use [<c-i> (this is square bracket followed by ctrl-i) to jump to the definition of the word under the cursor (even if it is in a different file), or [i to display the (first line of the) definition under the status line. For these and similar commands, see :help include-search.

Vim searches for files in the locations specified by the path option. You may need to adjust the value of path for the above to work (see :help 'path').

Integration with MetaPost

Vim offers excellent support for editing METAFONT and MetaPost documents (mf and mp filetypes). See :help ft-metapost for the details. Most of the features of such filetypes work also inside ConTeXt's MetaPost environments, such as \startMPpage… \stopMPpage.

In particular, Vim automatically highlights and indents MetaPost and MetaFun code inside a ConTeXt document. Besides, when you are inside a MetaPost environment, you may press CTRL-X followed by CTRL-O to complete a MetaPost/MetaFun keyword (see below for a list of several autocompletion plugins to streamline this). This works out of the box: no configuration is required. Watch the asciicast above for a demo.

Integration with other languages

Lua syntax highlighting is used inside \directlua{} and \ctxlua{} commands, and inside \startluacode… \stopluacode. XML highlighting is used inside \startXML… \stopXML.

You may embed other filetypes. Just define g:context_include (or b:context_include for buffer-specific settings). For example, if you want to highlight C++ code inside, say, \startCPP… \stopCPP, define:

let g:context_include = { 'cpp' : 'CPP' }

The key is the name of the filetype and the corresponding value is name of the command.

Using the scripts with an older Vim

If you are using an older Vim, you may copy the following scripts from Vim's distribution (https://github.com/vim/vim) into corresponding folders in your .vim folder (so, for example runtime/ftplugin/context.vim must be copied into ~/.vim/ftplugin/context.vim):

runtime/autoload/context.vim
runtime/autoload/contextcomplete.vim
runtime/compiler/context.vim
runtime/ftplugin/{context,mf,mp}.vim
runtime/indent/{context,mf,mp}.vim
runtime/syntax/{context,mf,mp}.vim

Note: the runtime scripts in Vim 9.0.0218 or later are written in Vim 9 script (the new scripting language embedded in Vim) and there is no guarantee that they will work with older versions of Vim!

If you get the following error when you open a ConTeXt or MetaPost document:

E410: Invalid :syntax subcommand: iskeyword

edit the syntax files and remove the syn iskeyword or syntax iskeyword line. Instead, put a corresponding command in ~/.vim/after/ftplugin/context.vim:

setlocal iskeyword=@,48-57,a-z,A-Z,192-255

and in ~/.vim/after/ftplugin/mp.vim for MetaPost:

setlocal iskeyword=@,_

Everything should work, at least with Vim 7.4.

TODO

Filetype detection

TeX (Plain TeX), LaTex and ConTeXt all use the .tex extension for files, which makes it difficult to detect the filetype based on the extension. From Vim 7 onwards, Vim does some intelligent checking to see it the file is plaintex or latex or context.

If the first line of a *.tex file has the form

%&<format>

then this determines the file type: plaintex (for Plain TeX), context (for ConTeXt), or tex (for LaTeX). Otherwise, the file is searched for keywords to choose context or tex. If no keywords are found, it defaults to plaintex. You can change the default by defining the variable g:tex_flavor to the format (not the file type) you use most. Use one of these:

let g:tex_flavor = "plain"
let g:tex_flavor = "context"
let g:tex_flavor = "latex"

Currently no other formats are recognized.

  • If you use ConTeXt most of the time, but occasionally use LaTeX or Plain TeX, you can add the following to your vimrc
let g:tex_flavor = "context"
  • If you only use ConTeXt, you can add the following lines to filetype.vim:
" ConTeXt
augroup filetypedetect
	au! BufRead,BufNewFile *.tex		setfiletype context
augroup END

so the next time you open a *.tex file, Vim will always recognize it as a ConTeXt document.

Spell checking

Vim 7 or later has a built-in spell checker. To enable it or disable it, use:

:set spell

or

:set nospell

respectively. To set the language to be used for spell checking, set the spelllang option accordingly. For example:

:set spelllang=en_us

Use lowercase letters (en_us, not en_US). When you set spelllang, Vim offers to download the language data into your .vim folder, if such language is not available. You can put the above settings in your vimrc if you like.

Powerful key mappings

In the following, <leader> denotes your “leader” (:help mapleader), that is, the prefix for user-defined mappings. By default, the leader is the backslash character, but that may be changed by the user. For example, to use a comma as a leader, put this in your vimrc:

map <leader> ,

Rather than overriding the default leader, you may define an alternative key. The <space> is a good choice, because by default it has the same function as the <right> key, and it is comfortable to type:

map <space> <leader>  " Use <space> as an alternative leader (backslash can still be used)

Clean up auxiliary files

The following function can be used to clean up temporary files:

fun! ConTeXtClean()
  let l:currdir = expand("%:p:h")
  let l:tmpdirs = ['out'] " Temporary directories
  let l:suffixes = ['aux', 'bbl', 'blg', 'fls', 'log', 'tuc'] " Suffixes of temporary files
  for ff in glob(l:currdir . '/*.{' . join(l:suffixes, ',') . '}', 1, 1)
    call delete(ff)
  endfor
  for dd in l:tmpdirs
    let l:subdir = l:currdir . '/' . dd
    if isdirectory(l:subdir)
      for ff in glob(l:subdir . '/*.{' . join(l:suffixes, ',') . '}', 1, 1)
        call delete(ff)
      endfor
    endif
    call delete(l:subdir) " Delete directory (only if empty)
  endfor
  echomsg "Aux files removed"
endf

Customize l:tmpdirs and l:suffixes to suit your needs. In Windows systems, you may have to replace each slash with a backslash, too.

The following mapping allows you to remove auxiliary files by pressing \tc:

nnoremap <silent><buffer> <leader>tc :<c-u>call ConTeXtClean()<cr>

Snippets

Vim allows you to define abbreviations for frequently used pieces of text (see :help abbreviations). Here are a few examples:

fun! Eatchar(pat)  " See :help abbreviations
   let c = nr2char(getchar(0))
   return (c =~ a:pat) ? '' : c
endfun

iab <buffer> ch- \startchapter[title={<c-o>ma}]<cr><c-o>mb<cr>\stopchapter<esc>`a`b<c-o>a<c-r>=Eatchar('\s')<cr>
iab <buffer> s- \startsection[title={<c-o>ma}]<cr><c-o>mb<cr>\stopsection<esc>`a`b<c-o>a<c-r>=Eatchar('\s')<cr>
iab <buffer> ss- \startsubsection[title={<c-o>ma}]<cr><c-o>mb<cr>\stopsubsection<esc>`a`b<c-o>a<c-r>=Eatchar('\s')<cr>
iab <buffer> sss- \startsubsubsection[title={<c-o>ma}]<cr><c-o>mb<cr>\stopsubsubsection<esc>`a`b<c-o>a<c-r>=Eatchar('\s')<cr>
iab <buffer> slide- \startslide[title={<c-o>ma}]<cr><c-o>mb<cr>\stopslide<esc>`a`b<c-o>a<c-r>=Eatchar('\s')<cr>
iab <buffer> fig- \startplacefigure<cr><tab>\externalfigure[<c-o>ma]%<cr>[]<c-o>mb<cr><c-d>\stopplacefigure<esc>`a`b<c-o>a<c-r>=Eatchar('\s')<cr>
iab <buffer> item- \startitemize<cr><cr>\stopitemize<up><tab>\item
iab <buffer> enum- \startitemize[n]<cr><cr>\stopitemize<up><tab>\item
iab <buffer> i- \item

Type the abbreviation followed by Space to expand the snippet, then continue typing normally.

Inside the definition of an abbreviation, marks may be set (see :h m), which allow you to jump between the different parts of a snippet with TAB (CTRL-i) and CTRL-O (in Normal mode) after the abbreviation is expanded (see :h jump-motions). For example, after typing ch- , the cursor will be at the title's position. If you press <esc><tab> (or <c-o><tab> if you want to stay in Insert mode after the jump), you will jump between \startchapter and \stopchapter.

Buffer-local Insert-mode macros to speed up editing

(By D.A. 19:52, 8 Jul 2005 (CEST))

  • I have remapped <leader> to comma (one hardly ever use commas just before a letter)
  • two types of mappings: stand-alone and changing the previous word
  • usage of mappings that change the previous word: type the name of the macro and ,ta (for tag, use your leader character instead of the comma); it created \start-\stop block of the macro
  • put the code into .vim/after/plugin/context.vim
let maplocalleader = mapleader

" Make start-stop block out of the previous word
imap <buffer> <LocalLeader>ta \start<Cr>\stop<Cr><Esc>4bhdiw$pj$pO
imap <buffer> <LocalLeader>tb \begin<Cr>\end<Cr><Esc>4bhdiw$pj$pO

" Itemize
imap <buffer> <LocalLeader>it \startitemize<Cr>\stopitemize<Esc>O\item<Space>
imap <buffer> <LocalLeader>en \startitemize[n]<Cr>\stopitemize<Esc>O\item<Space>
imap <buffer> <LocalLeader>i<Return> \item<Space>

" Font switching and emphasize
imap <buffer> <LocalLeader>em {\em }<Left>
imap <buffer> <LocalLeader>sc {\sc }<Left>

" Define... and setup...
imap <buffer> <LocalLeader>de \define
imap <buffer> <LocalLeader>se \setup

" Typing and type
imap <buffer> <LocalLeader>ty \type{}<Left>
imap <buffer> <LocalLeader>typ typing<LocalLeader>ta

" Quote and quotation
imap <buffer> <LocalLeader>" \quotation{}<Left>
imap <buffer> <LocalLeader>' \quote{}<Left>

Key mappings borrowed from SciTE

If you use the stand-alone distribution for Windows/Linux. You can reset the key mapping to speed ConTeXt compiling.

Just add the following code to your _vimrc (or .vimrc file under Linux) file:

"run setup and complie, then open the result pdf file
 map <F5> <Esc><Esc>:sil ! "D:\context\tex\setuptex.bat && texmfstart texexec.pl --autopdf --pdf '%'"<CR><CR>

"view the corresponding pdf file
map <F6> <Esc><Esc>:sil ! D:\"Program Files"\Adobe\Acrobat\Acrobat.exe %:p:r.pdf<CR><CR>

"run setup and make purge
map <F7> <Esc><Esc>:sil ! "D:\context\tex\setuptex.bat && texmfstart texutil.pl --purge"<CR><CR>

"run setup and make list of the current file
map <F8> <Esc><Esc>:sil ! "D:\context\tex\setuptex.bat && texmfstart texexec.pl --autopdf --pdf --list --result=%:p:r_list %"<CR><CR>

Quickfix mappings

It is useful to define mappings for quickfix commands, to be able to navigate among ConTeXt errors. For example:

 nnoremap <silent> ]q :<c-u><c-r>=v:count1<cr>cnext<cr>zz
 nnoremap <silent> [q :<c-u><c-r>=v:count1<cr>cprevious<cr>zz
 nnoremap <silent> ]Q :<c-u>clast<cr>zz
 nnoremap <silent> [Q :<c-u>cfirst<cr>zz

Or install Tim Pope's unimpaired plugin.

Makefiles

For your ConTeXt document, you can prepare a Makefile like this one (Contributed by Buggs):

# An example Makefile to compile a context file, paper.tex
paper.pdf: paper.tex
    context paper

test:
    xpdf paper.pdf

clean:
    rm *.aux *.bbl *.blg *.log *.tuc

If you put these mappings to your vimrc file, you can then compile the document with F9 and preview it with F8:

" map ":make" to the F9 key
imap <F9> <ESC>:exe "lcd" fnameescape(expand("%:p:h"))<CR>:make<CR>
nmap <F9> :exe "lcd" fnameescape(expand("%:p:h"))<CR>:make<CR>

"map ":make test" to the F8 key
imap <F8> <ESC>:exe "lcd" fnameescape(expand("%:p:h"))<CR>:make test<CR>
nmap <F8> :exe "lcd" fnameescape(expand("%:p:h"))<CR>:make test<CR>

Note that if you use :make typesetting will happen synchronously.

Other useful Vim plugins

Autocompletion

Vim offers a rich completion mechanism (:help ins-completion), but there are several plugins that improve on it, in particular, to provide automatic completion of keywords:

  • MUcomplete[2]
  • Coc [3].
  • Completor[4]
  • NeoComplete[5]
  • Deoplete (for NeoVim)[6]
  • YouCompleteMe[7]
  • AutoComplPop[8]
  • SuperTab[9]

In the asciicast at the top of this page MUcomplete was used.

UltiSnips

UltiSnips[10] is a sophisticated snippets manager. Here are a few examples of useful UltiSnips snippets for ConTeXt:

snippet "s(tart)?" "start / stop" br
\start${1:something}$2
	${3:${VISUAL}}
\stop$1
endsnippet

snippet enum "Enumerate" b
\startitemize[n]
	\item ${0:${VISUAL}}
\stopitemize
endsnippet

snippet item "Itemize" b
\startitemize
	\item
	${0:${VISUAL}}
\stopitemize
endsnippet

snippet it "Individual item" b
\item
${0:${VISUAL}}
endsnippet

snippet fig "External figure" b
\startplacefigure
	\externalfigure[${1:${VISUAL}}][$2]
\stopplacefigure
endsnippet

Save the above text into ~/.vim/UltiSnips/context.snippets. Click on the asciicast linked at the top of this document to see UltiSnips snippets in action.

Outline of a document

Tagbar[11] is a useful plugin to display an outline or a table of contents of a document. It uses Ctags, which you must install, too. Ctags does not support ConTeXt out of the box, but it is easy to extend. Create a .ctags file in your home directory, then copy and paste the following:

--langdef=context
--regex-context=/^[[:space:]]*\\startsection[[:space:]]*\[[^]]*title[[:space:]]*=[[:space:]]*\{[[:space:]]*(.+)\}/\. \1/s,section/
--regex-context=/^[[:space:]]*\\startsubsection[[:space:]]*\[[^]]*title[[:space:]]*=[[:space:]]*\{[[:space:]]*(.+)\}/\.\. \1/s,subsection/
--regex-context=/^[[:space:]]*\\startsubsubsection[[:space:]]*\[[^]]*title[[:space:]]*=[[:space:]]*\{[[:space:]]*(.+)\}/\.\.\. \1/s,subsubsection/
--regex-context=/^[[:space:]]*\\startchapter[[:space:]]*\[[^]]*title[[:space:]]*=[[:space:]]*\{[[:space:]]*(.+)\}/\1/c,chapter/
--regex-context=/^[[:space:]]*\\startsubject[[:space:]]*\[[^]]*title[[:space:]]*=[[:space:]]*\{[[:space:]]*(.+)\}/SUBJ \1/c,subject/
--regex-context=/^[[:space:]]*\\startpart[[:space:]]*\[[^]]*title[[:space:]]*=[[:space:]]*\{[[:space:]]*(.+)\}/\1/p,part/

Put this in your vimrc:

   let g:tagbar_type_context = {
         \ 'ctagstype': 'context',
         \ 'kinds': [
         \ 'p:parts',
         \ 'c:chapters',
         \ 's:sections'
         \ ],
         \ 'sort': 0
         \ }

That's it! See the image at the top of this document for an example.

Using LaTeX-Suite

latex-suite currently doesn't support ConTeXt, but if you use it, here's what you have to do to compile ConTeXt documents:

1. After downloading and installing latex-suite, locate the file "texrc" (usually located in ~/.vim/ftplugin/latex-suite). Copy this file to ~/.vim/ftplugin/tex/texrc

2. Open this copy in your favorite editor (vim comes to mind...)

3. After line 80 in this file, there is a series of "Compiler rules." Just add this line to the section:

TexLet g:Tex_CompileRule_cont = 'texexec --pdf --nonstopmode $*'

This will add compilation for ConTeXT. In order to use it:

4. When you're in vim normal mode, run this command:

TGTarget cont [that's "colon TGTarger cont"] 

5. Edit your TeX-files, save the changes; when you want to compile, switch to normal mode and just type \ll (that's 'backslash el el' )

Voila, compilation should start. You'll have to specify this compiler target every timeI you open a TeX-file in Vim. If you want to make this the default compiler, you should have this line in your texrc:

TexLet g:Tex_DefaultTargetFormat = 'cont'